From 33ef395470e723eac3146655eace0843d3eb2ed4 Mon Sep 17 00:00:00 2001
From: Justin Gassner <justin.gassner@web.de>
Date: Sat, 7 Oct 2017 16:24:59 +0200
Subject: Initial commit

---
 neovim/PKGBUILD | 50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 neovim/PKGBUILD

(limited to 'neovim')

diff --git a/neovim/PKGBUILD b/neovim/PKGBUILD
new file mode 100644
index 0000000..38ded77
--- /dev/null
+++ b/neovim/PKGBUILD
@@ -0,0 +1,50 @@
+# Maintainer: Justin Gassner <justin.gassner@web.de>
+
+_pkgname=neovim
+pkgname=$_pkgname-jxir
+pkgver=0.2.0.r922.g01487d438
+pkgrel=1
+pkgdesc='Fork of Vim aiming to improve user experience, plugins, and GUIs'
+arch=('i686' 'x86_64')
+url='https://neovim.io'
+license=('custom:neovim')
+depends=('jemalloc' 'libtermkey' 'libuv' 'libvterm' 'luajit' 'msgpack-c' 'unibilium')
+makedepends=('cmake' 'git' 'gperf' 'lua51-lpeg' 'lua51-mpack')
+optdepends=('python2-neovim: for Python 2 plugin support (see :help provider-python)'
+            'python-neovim: for Python 3 plugin support (see :help provider-python)'
+            'ruby-neovim: for Ruby plugin support (see :help provider-ruby)'
+            'xclip: for clipboard support (or xsel) (see :help provider-clipboard)'
+            'xsel: for clipboard support (or xclip) (see :help provider-clipboard)')
+provides=("$_pkgname")
+conflicts=("$_pkgname")
+source=("git+https://github.com/$_pkgname/$_pkgname.git")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "$_pkgname"
+  git describe --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  mkdir -p "$_pkgname/build"
+  cd "$_pkgname/build"
+  cmake -G 'Unix Makefiles' \
+        -DCMAKE_BUILD_TYPE=Release \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DENABLE_JEMALLOC=ON \
+        ..
+  make
+}
+
+check() {
+  cd "$_pkgname/build"
+  ./bin/nvim --version
+  ./bin/nvim --headless -u NONE -i NONE -c ':quit'
+}
+
+package() {
+  cd "$_pkgname/build"
+  make DESTDIR="$pkgdir" install
+  install -Dm644 ../LICENSE "$pkgdir/usr/share/licenses/$_pkgname/LICENSE"
+  ln -s nvim "$pkgdir/usr/bin/vim"
+}
-- 
cgit v1.2.3-54-g00ecf