# Maintainer: Justin Gassner <justin.gassner@web.de>

_pkgname=ffmpeg
pkgname=$_pkgname-jxir
pkgver=3.3.4
pkgrel=1
epoch=1
pkgdesc='Complete solution to record, convert and stream audio and video'
arch=('i686' 'x86_64')
url='https://ffmpeg.org/'
license=('GPL3')
depends=('alsa-lib' 'bzip2' 'fontconfig' 'libass' 'zlib')
makedepends=('yasm')
provides=('libavcodec.so' 'libavdevice.so' 'libavfilter.so' 'libavformat.so'
          'libavutil.so' 'libpostproc.so' 'libswresample.so'
          'libswscale.so' 'ffmpeg')
conflicts=('ffmpeg')
source=("http://ffmpeg.org/releases/$_pkgname-$pkgver.tar.xz"{,.asc})
sha256sums=('98b97e1b908dfeb6aeb6d407e5a5eacdfc253a40c2d195f5867ed2d1d46ea957'
            'SKIP')
validpgpkeys=('FCF986EA15E6E293A5644F10B4322F04D67658D8')

build() {
  cd "$srcdir/$_pkgname-$pkgver"
  ./configure \
    --prefix='/usr' \
    --enable-gpl \
    --enable-version3 \
    --disable-static \
    --enable-shared \
    --disable-runtime-cpudetect \
    --disable-swscale-alpha \
    --disable-ffplay \
    --disable-ffserver \
    --disable-doc \
    --disable-network \
    --disable-everything \
    --enable-encoder=libvorbis \
    --enable-decoder=aac,h264,libvorbis \
    --enable-muxer=mp4,ogg \
    --enable-demuxer=aac,ass,h264,matroska,mov,ogg \
    --enable-parser=aac,h264,vorbis \
    --enable-protocol=file \
    --enable-libass \
    --enable-libfontconfig \
    --enable-libfreetype \
    --disable-debug
  make
}

package() {
  cd "$srcdir/$_pkgname-$pkgver"
  make DESTDIR="$pkgdir" install install-man
}