# Maintainer: Justin Gassner <justin.gassner@mailbox.org>

_pkgname=ffmpeg
pkgname=$_pkgname-jxir
pkgver=4.3.r1387.gf7ad9a6c16
pkgrel=1
pkgdesc='Complete solution to record, convert and stream audio and video'
arch=('x86_64')
url='https://ffmpeg.org/'
license=('GPL3')
depends=('alsa-lib' 'libass' 'libva')
makedepends=('git' 'nasm')
provides=('libavcodec.so' 'libavdevice.so' 'libavfilter.so' 'libavformat.so'
          'libavutil.so' 'libpostproc.so' 'libswresample.so' 'libswscale.so'
          'ffmpeg')
conflicts=('ffmpeg')
source=('git+https://git.ffmpeg.org/ffmpeg.git')
sha256sums=('SKIP')

pkgver() {
  cd "$srcdir/$_pkgname"
  git describe --long | sed 's/n//;s/-dev//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "$srcdir/$_pkgname"
  ./configure \
    --prefix='/usr' \
    --enable-gpl \
    --enable-version3 \
    --disable-static \
    --enable-shared \
    --disable-runtime-cpudetect \
    --disable-swscale-alpha \
    --disable-ffplay \
    --disable-doc \
    --disable-network \
    --disable-everything \
    --enable-rdft \
    --enable-decoder=aac,h264,opus \
    --enable-hwaccel=h264_vaapi,vp9_vaapi \
    --enable-muxer=mp4,matroska,webm \
    --enable-demuxer=aac,ass,h264,matroska,mov \
    --enable-parser=aac,h264,opus,vp9 \
    --enable-bsf=vp9_superframe \
    --enable-protocol=file \
    --enable-libass \
    --enable-libfontconfig \
    --enable-libfreetype \
    --disable-debug
  make
}

package() {
  cd "$srcdir/$_pkgname"
  make DESTDIR="$pkgdir" install install-man
}