# Maintainer: Justin Gassner <justin.gassner@web.de>

_pkgname=mpop
pkgname=$_pkgname-jxir
pkgver=1.2.6
pkgrel=1
pkgdesc='A small, fast POP3 client'
arch=('i686' 'x86_64')
url="http://$_pkgname.sourceforge.net"
license=('GPL3')
depends=('gsasl')
makedepends=('texlive-plainextra')
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("http://downloads.sourceforge.net/$_pkgname/$_pkgname-$pkgver.tar.xz"{,.sig}
        'change-configuration-file-location.patch')
sha256sums=('9fec7a9dd08fc0f04bf6178bc651b036d1fe0e46903146f38a8d182887e9315c'
            'SKIP'
            'ca36ec82129c14a1f69d51beb89fcd2a6a79ec4d2eac7f4248207c9aaf2229a4')
validpgpkeys=('2F788CDEF4181652720EF132F4926138953E5294') # Martin Lambers

prepare() {
  cd "$srcdir/$_pkgname-$pkgver"
  patch -p1 -i "$srcdir/change-configuration-file-location.patch"
}

build() {
  cd "$srcdir/$_pkgname-$pkgver"
  ./configure \
    --prefix=/usr \
    --disable-nls \
    --with-tls=gnutls \
    --without-libsecret
  make
  make -C doc pdf
}

package() {
  cd "$srcdir/$_pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
  make DESTDIR="$pkgdir" -C doc install-pdf
  install -D -m644 doc/*.example "$pkgdir/usr/share/doc/$_pkgname/"
  install -D -m644 "scripts/vim/$_pkgname.vim" "$pkgdir/usr/share/nvim/runtime/syntax/$_pkgname.vim"
}