# Maintainer: Justin Gassner <justin.gassner@mailbox.org>

_pkgname=msmtp
pkgname=$_pkgname-jxir
pkgver=1.8.6.r0.g2131126
pkgrel=1
pkgdesc='A small, fast SMTP client'
arch=('x86_64')
url="https://marlam.de/$_pkgname/"
license=('GPL3')
depends=('gnutls' 'gsasl')
makedepends=('git' 'texlive-plainextra')
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("git+https://git.marlam.de/git/$_pkgname.git")
sha256sums=('SKIP')

pkgver() {
  cd "$srcdir/$_pkgname"
  git describe --long | sed "s/$_pkgname-//;s/\([^-]*-g\)/r\1/;s/-/./g"
}

build() {
  cd "$srcdir/$_pkgname"
  autoreconf -i
  ./configure \
    --prefix=/usr \
    --disable-nls \
    --with-tls=gnutls \
    --with-libgsasl \
    --without-libsecret \
    --without-msmtpd
  make
  make -C doc pdf
}

package() {
  cd "$srcdir/$_pkgname"
  make DESTDIR="$pkgdir" install
  make DESTDIR="$pkgdir" -C doc install-pdf
  install -Dm644 doc/*.example "$pkgdir/usr/share/doc/$_pkgname/"
  install -Dm644 "scripts/vim/$_pkgname.vim" "$pkgdir/usr/share/nvim/runtime/syntax/$_pkgname.vim"
}