# Maintainer: Justin Gassner <justin.gassner@web.de>

_pkgname=msmtp
pkgname=$_pkgname-jxir
pkgver=1.6.6
pkgrel=1
pkgdesc='A small, fast SMTP client'
arch=('x86_64')
url="http://$_pkgname.sourceforge.net"
license=('GPL3')
depends=('gsasl')
makedepends=('texlive-plainextra')
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("http://downloads.sourceforge.net/$_pkgname/$_pkgname-$pkgver.tar.xz"{,.sig}
        'change-configuration-file-location.patch')
sha256sums=('da15db1f62bd0201fce5310adb89c86188be91cd745b7cb3b62b81a501e7fb5e'
            'SKIP'
            '46bb7505e7a2298846cb03ba4cacc4b1cabd09bb425715a02d2c3ec1a7780ad4')
validpgpkeys=('2F788CDEF4181652720EF132F4926138953E5294') # Martin Lambers

prepare() {
  cd "$srcdir/$_pkgname-$pkgver"
  patch -p1 -i "$srcdir/change-configuration-file-location.patch"
}

build() {
  cd "$srcdir/$_pkgname-$pkgver"
  ./configure \
    --prefix=/usr \
    --disable-nls \
    --with-tls=gnutls \
    --without-libsecret
  make
  make -C doc pdf
}

package() {
  cd "$srcdir/$_pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
  make DESTDIR="$pkgdir" -C doc install-pdf
  install -Dm644 doc/*.example "$pkgdir/usr/share/doc/$_pkgname/"
  install -Dm644 "scripts/vim/$_pkgname.vim" "$pkgdir/usr/share/nvim/runtime/syntax/$_pkgname.vim"
}