# Maintainer: Justin Gassner <justin.gassner@web.de>

_pkgname=mutt
pkgname=$_pkgname-jxir
pkgver=1.9.4
pkgrel=1
pkgdesc='Small but very powerful text-based mail client'
arch=('x86_64')
url='http://www.mutt.org'
license=('GPL')
depends=('gpgme' 'libidn' 'ncurses')
source=("http://ftp.mutt.org/pub/mutt/$_pkgname-$pkgver.tar.gz"{,.asc})
sha256sums=('f4d1bf26350c1ac81b551f98e5a4fd80d7fecd86919aa8165e69fde87de1b5df'
            'SKIP')
validpgpkeys=('8975A9B33AA37910385C5308ADEF768480316BDA') # Kevin McCarthy

build() {
  cd "$srcdir/$_pkgname-$pkgver"
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --enable-gpgme \
    --disable-pgp \
    --enable-sidebar \
    --enable-hcache \
    --disable-nls \
    --disable-full-doc \
    --with-curses=/usr \
    --with-regex
  make
}

package() {
  cd "$srcdir/$_pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
  rm "$pkgdir"/etc/Muttrc.dist
  rm "$pkgdir"/etc/mime.types{,.dist}
  rm "$pkgdir"/usr/share/man/man1/{pgpewrap,pgpring}.1
  rm -r "$pkgdir"/usr/share/doc/mutt/samples/
  rm "$pkgdir"/usr/share/doc/mutt/{applying-patches.txt,devel-notes.txt,patch-notes.txt,PGP-Notes.txt,smime-notes.txt}
  rm "$pkgdir"/usr/share/doc/mutt/{ChangeLog,COPYRIGHT,GPL,INSTALL,NEWS,README,README.SECURITY,README.SSL,TODO}
  rm "$pkgdir"/usr/share/doc/mutt/{manual.txt,manual.html}
}