Add slock

1 files changed, 41 insertions, 0 deletions

diff --git a/slock/PKGBUILD b/slock/PKGBUILD
new file mode 100644
index 0000000..3d7e8f7
--- /dev/null
+++ b/slock/PKGBUILD
@@ -0,0 +1,41 @@
+# Maintainer: Justin Gassner <justin.gassner@web.de>
+
+_pkgname=slock
+pkgname=$_pkgname-jxir
+pkgver=1.4.6.g2aa4369
+pkgrel=1
+pkgdesc='A simple screen locker for X'
+arch=('x86_64')
+url="https://tools.suckless.org/$_pkgname"
+license=('MIT')
+depends=('libxext' 'libxrandr')
+makedepends=('ncurses' 'git')
+provides=("$_pkgname")
+conflicts=("$_pkgname")
+source=("git+https://git.jxir.de/$_pkgname")
+sha256sums=('SKIP')
+
+pkgver(){
+  cd "$_pkgname"
+  git describe --tags | sed 's/-/./g'
+}
+
+prepare() {
+  cd "$_pkgname"
+  for branch in config; do
+    git merge --no-edit origin/$branch
+  done
+  mv config.def.h config.h
+}
+
+build() {
+  cd "$_pkgname"
+  make X11INC=/usr/include/X11 X11LIB=/usr/lib/X11
+}
+
+package() {
+  cd "$_pkgname"
+  make PREFIX=/usr DESTDIR="$pkgdir" install
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$_pkgname/LICENSE"
+  install -Dm644 README "$pkgdir/usr/share/doc/$_pkgname/README"
+}