1 files changed, 91 insertions, 0 deletions
diff --git a/mpv/PKGBUILD b/mpv/PKGBUILD
new file mode 100644
index 0000000..e1763dc
--- /dev/null
+++ b/mpv/PKGBUILD
@@ -0,0 +1,91 @@
+# Maintainer: Justin Gassner <justin.gassner@mailbox.org>
+
+_pkgname=mpv
+pkgname=$_pkgname-jxir
+epoch=1
+pkgver=0.29.0.r723.g3ee6d7db4e
+pkgrel=1
+pkgdesc='a free, open source, and cross-platform media player'
+arch=('x86_64')
+license=('GPL')
+url='https://mpv.io'
+depends=('ffmpeg' 'libarchive' 'libxinerama' 'libxrandr' 'libxss' 'lua52')
+makedepends=('mesa' 'python-docutils')
+optdepends=('youtube-dl: for video-sharing websites playback')
+provides=("$_pkgname")
+conflicts=("$_pkgname")
+source=('git+https://github.com/mpv-player/mpv')
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "$srcdir/$_pkgname"
+  git describe --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g;'
+}
+
+prepare() {
+  cd "$srcdir/$_pkgname"
+  ./bootstrap.py
+}
+
+build() {
+  cd "$srcdir/$_pkgname"
+  ./waf configure \
+    --prefix=/usr \
+    --confdir=/etc/mpv \
+    --disable-debug-build \
+    --enable-manpage-build \
+    --disable-android \
+    --disable-javascript \
+    --disable-libbluray \
+    --disable-uchardet \
+    --disable-rubberband \
+    --disable-zimg \
+    --disable-lcms2 \
+    --disable-vapoursynth \
+    --disable-libavdevice \
+    --lua=52arch \
+    --disable-oss-audio \
+    --disable-rsound \
+    --disable-pulse \
+    --disable-jack \
+    --disable-opensles \
+    --disable-coreaudio \
+    --disable-audiounit \
+    --disable-wasapi \
+    --disable-cocoa \
+    --disable-drm \
+    --disable-drmprime \
+    --disable-gbm \
+    --disable-wayland-scanner \
+    --disable-wayland-protocols \
+    --disable-wayland \
+    --disable-xv \
+    --disable-vdpau \
+    --enable-vaapi \
+    --disable-caca \
+    --disable-jpeg \
+    --disable-direct3d \
+    --disable-shaderc \
+    --disable-spirv-cross \
+    --disable-rpi \
+    --disable-ios-gl \
+    --disable-libplacebo \
+    --disable-vulkan \
+    --disable-videotoolbox-gl \
+    --disable-d3d-hwaccel \
+    --disable-d3d9-hwaccel \
+    --disable-gl-dxinterop-d3d9 \
+    --disable-cuda-hwaccel \
+    --disable-apple-remote \
+    --disable-macos-touchbar
+  ./waf build
+}
+
+package() {
+  cd "$srcdir/$_pkgname"
+  ./waf install --destdir="$pkgdir"
+  rm -rf "$pkgdir/usr/share/applications/"
+  rm -rf "$pkgdir/usr/share/doc/mpv/mplayer-input.conf"
+  rm -rf "$pkgdir/usr/share/doc/mpv/restore-old-bindings.conf"
+  rm -rf "$pkgdir/usr/share/icons/"
+}