1 files changed, 39 insertions, 0 deletions
diff --git a/pinentry/PKGBUILD b/pinentry/PKGBUILD
new file mode 100644
index 0000000..bbd630b
--- /dev/null
+++ b/pinentry/PKGBUILD
@@ -0,0 +1,39 @@
+# Maintainer: Justin Gassner <justin.gassner@mailbox.org>
+
+_pkgname=pinentry
+pkgname=$_pkgname-jxir
+pkgver=1.1.0
+pkgrel=4
+pkgdesc='Collection of simple PIN or passphrase entry dialogs which utilize the Assuan protocol'
+arch=('x86_64')
+url='https://gnupg.org/related_software/pinentry/'
+license=('GPL')
+depends=('libassuan')
+provides=("$_pkgname")
+conflicts=("$_pkgname")
+source=("https://gnupg.org/ftp/gcrypt/$_pkgname/$_pkgname-$pkgver.tar.bz2"{,.sig})
+sha256sums=('68076686fa724a290ea49cdf0d1c0c1500907d1b759a3bcbfbec0293e8f56570'
+            'SKIP')
+validpgpkeys=('D8692123C4065DEA5E0F3AB5249B39D24F25E3B6')
+
+build() {
+  cd "$srcdir/$_pkgname-$pkgver"
+  ./configure \
+    --prefix=/usr \
+    --enable-pinentry-curses \
+    --enable-fallback-curses \
+    --enable-pinentry-tty \
+    --disable-pinentry-emacs \
+    --disable-inside-emacs \
+    --disable-pinentry-gtk2 \
+    --disable-pinentry-gnome3 \
+    --disable-libsecret \
+    --disable-pinentry-qt \
+    --without-libcap
+  make
+}
+
+package() {
+  cd "$srcdir/$_pkgname-$pkgver"
+  make DESTDIR="$pkgdir" install
+}