blob: 4bac52c249eda8d6e6c290273f45963e55f46967 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: Justin Gassner <justin.gassner@mailbox.org>
_pkgname=gnuplot
pkgname=$_pkgname-jxir
pkgver=5.2.7
pkgrel=1
pkgdesc='Plotting package which outputs to X11, PostScript, PNG, GIF, and others'
arch=('x86_64')
url='http://www.gnuplot.info'
license=('custom')
depends=('pango' 'lua')
makedepends=('texinfo')
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("https://downloads.sourceforge.net/sourceforge/$_pkgname/$_pkgname-$pkgver.tar.gz")
sha256sums=('97fe503ff3b2e356fe2ae32203fc7fd2cf9cef1f46b60fe46dc501a228b9f4ed')
prepare() {
cd "$_pkgname-$pkgver"
# fix default source location; use the GDFONTPATH variable to modify at runtime
sed -i 's|/usr/X11R6/lib/X11/fonts/truetype|/usr/share/fonts/TTF|' src/variable.c
sed -i -e 's|/usr/X11R6/lib/X11/fonts/Type1|/usr/share/fonts/Type1|' \
-e 's|$(X11ROOT)/X11R6/lib/X11/fonts/Type1|$(X11ROOT)/usr/share/fonts/Type1|' \
src/variable.c
}
build() {
cd "$_pkgname-$pkgver"
./configure \
--prefix=/usr \
--libexecdir=/usr/bin \
--disable-history-file \
--disable-wxwidgets \
--with-texdir=/usr/share/texmf-dist/tex/latex/gnuplot \
--with-gihdir=/usr/share/gnuplot \
--without-libcerf \
--without-latex \
--without-x \
--without-linux-vga \
--with-readline=gnu \
--without-gd \
--without-qt
make
}
package() {
cd "$_pkgname-$pkgver"
make pkglibexecdir=/usr/bin DESTDIR="$pkgdir" install
install -Dm644 Copyright "$pkgdir/usr/share/licenses/$pkgname/Copyright"
rm -f "$pkgdir/usr/share/texmf-dist/ls-R"
}
|