blob: fc93e339025957cae8da38f6fbed769fdc09cf81 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Justin Gassner <justin.gassner@mailbox.org>
_pkgname=mpop
pkgname=$_pkgname-jxir
pkgver=1.4.6.r0.g7d3a000
pkgrel=1
pkgdesc='A small, fast POP3 client'
arch=('x86_64')
url="https://marlam.de/$_pkgname/"
license=('GPL3')
depends=('gnutls')
makedepends=('git' 'texlive-plainextra')
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("git+https://git.marlam.de/git/$_pkgname.git")
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/$_pkgname"
git describe --long | sed "s/$_pkgname-//;s/\([^-]*-g\)/r\1/;s/-/./g"
}
build() {
cd "$srcdir/$_pkgname"
autoreconf -i
./configure \
--prefix=/usr \
--disable-nls \
--with-tls=gnutls \
--without-libsecret
make
make -C doc pdf
}
package() {
cd "$srcdir/$_pkgname"
make DESTDIR="$pkgdir" install
make DESTDIR="$pkgdir" -C doc install-pdf
install -Dm644 doc/*.example "$pkgdir/usr/share/doc/$_pkgname/"
install -Dm644 "scripts/vim/$_pkgname.vim" "$pkgdir/usr/share/nvim/runtime/syntax/$_pkgname.vim"
}
|