1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Justin Gassner <justin.gassner@web.de>
_pkgname=mutt
pkgname=$_pkgname-jxir
pkgver=1.9.1
pkgrel=1
pkgdesc='Small but very powerful text-based mail client'
arch=('x86_64')
url='http://www.mutt.org'
license=('GPL')
depends=('gpgme' 'libidn' 'ncurses')
source=("http://ftp.mutt.org/pub/mutt/$_pkgname-$pkgver.tar.gz"{,.asc})
sha256sums=('749b83a96373c6e2101ebe8c4b9a651735e02c478edb750750a5146a15d91bb1'
'SKIP')
validpgpkeys=('8975A9B33AA37910385C5308ADEF768480316BDA') # Kevin McCarthy
build() {
cd "$srcdir/$_pkgname-$pkgver"
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--enable-gpgme \
--disable-pgp \
--enable-sidebar \
--enable-hcache \
--disable-nls \
--disable-full-doc \
--with-curses=/usr \
--with-regex
make
}
package() {
cd "$srcdir/$_pkgname-$pkgver"
make DESTDIR="$pkgdir" install
rm "$pkgdir"/etc/Muttrc.dist
rm "$pkgdir"/etc/mime.types{,.dist}
rm "$pkgdir"/usr/bin/{flea,muttbug}
rm "$pkgdir"/usr/share/man/man1/{flea,muttbug,pgpewrap,pgpring}.1
rm -r "$pkgdir"/usr/share/doc/mutt/samples/
rm "$pkgdir"/usr/share/doc/mutt/{applying-patches.txt,devel-notes.txt,patch-notes.txt,PGP-Notes.txt,smime-notes.txt}
rm "$pkgdir"/usr/share/doc/mutt/{ChangeLog,COPYRIGHT,GPL,INSTALL,NEWS,README,README.SECURITY,README.SSL,TODO}
rm "$pkgdir"/usr/share/doc/mutt/{manual.txt,manual.html}
}
|
