blob: edfc778eaf32e3082ceb06692cca75a4d5baece3 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: Justin Gassner <justin.gassner@web.de>
_pkgname=neovim
pkgname=$_pkgname-jxir
pkgver=0.2.0.r922.g01487d438
pkgrel=1
pkgdesc='Fork of Vim aiming to improve user experience, plugins, and GUIs'
arch=('x86_64')
url='https://neovim.io'
license=('custom:neovim')
depends=('jemalloc' 'libtermkey' 'libuv' 'libvterm' 'luajit' 'msgpack-c' 'unibilium')
makedepends=('cmake' 'git' 'gperf' 'lua51-lpeg' 'lua51-mpack')
optdepends=('python2-neovim: for Python 2 plugin support (see :help provider-python)'
'python-neovim: for Python 3 plugin support (see :help provider-python)'
'ruby-neovim: for Ruby plugin support (see :help provider-ruby)'
'xclip: for clipboard support (or xsel) (see :help provider-clipboard)'
'xsel: for clipboard support (or xclip) (see :help provider-clipboard)')
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("git+https://github.com/$_pkgname/$_pkgname.git")
sha256sums=('SKIP')
pkgver() {
cd "$_pkgname"
git describe --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
mkdir -p "$_pkgname/build"
cd "$_pkgname/build"
cmake -G 'Unix Makefiles' \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DENABLE_JEMALLOC=ON \
..
make
}
check() {
cd "$_pkgname/build"
./bin/nvim --version
./bin/nvim --headless -u NONE -i NONE -c ':quit'
}
package() {
cd "$_pkgname/build"
make DESTDIR="$pkgdir" install
install -Dm644 ../LICENSE "$pkgdir/usr/share/licenses/$_pkgname/LICENSE"
ln -s nvim "$pkgdir/usr/bin/vim"
}
|
