blob: 67a36a93cf01148d5d73993ec290a96a2859f9c2 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Justin Gassner <justin.gassner@mailbox.org>
_pkgname=st
pkgname=$_pkgname-jxir
pkgver=0.8.2.r24.g7e5b23e
pkgrel=1
pkgdesc='A simple virtual terminal emulator for X'
arch=('x86_64')
url="https://$_pkgname.suckless.org"
license=('MIT')
depends=('libxft')
makedepends=('git' 'ncurses')
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("git+https://git.jxir.de/$_pkgname")
sha256sums=('SKIP')
pkgver(){
cd "$_pkgname"
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "$_pkgname"
for branch in no-bold-colors solarized-dark scrollback config; do
git merge --no-edit origin/$branch
done
echo "CPPFLAGS+=${CPPFLAGS}" >> config.mk
echo "CFLAGS+=${CFLAGS}" >> config.mk
echo "LDFLAGS+=${LDFLAGS}" >> config.mk
mv config.def.h config.h
}
build() {
cd "$_pkgname"
make X11INC=/usr/include/X11 X11LIB=/usr/lib/X11
}
package() {
cd "$_pkgname"
make PREFIX=/usr DESTDIR="$pkgdir" install
install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
install -Dm644 README -t "$pkgdir/usr/share/doc/$_pkgname"
}
|
