blob: 48e46757cd9f6313a022e2ff83fba14bccf5b511 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Justin Gassner <justin.gassner@mailbox.org>
_pkgname=vifm
pkgname=$_pkgname-jxir
pkgver=0.10.1.r10.gae71417b7
pkgrel=1
pkgdesc='A file manager with curses interface, which provides Vi[m]-like environment'
arch=('x86_64')
url="https://vifm.info/"
license=('GPL')
depends=('file' 'bash')
optdepends=('perl: vifm-convert-dircolors')
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("git+https://github.com/$_pkgname/$_pkgname.git")
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/$_pkgname"
git describe --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g;'
}
build() {
cd "$srcdir/$_pkgname"
autoreconf -i
./configure \
--prefix=/usr \
--disable-desktop-files \
--without-gtk \
--without-X11
make
}
package() {
cd "$srcdir/$_pkgname"
make DESTDIR="$pkgdir" install
rm -rf "$pkgdir/usr/share/applications/"
rm -rf "$pkgdir/usr/share/pixmaps/"
rm -rf "$pkgdir/usr/share/vifm/"{vifm-media,vifmrc}-osx
}
|