blob: 3b68c2535d677f6a564fb2d19cf6be71372a60f0 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Justin Gassner <justin.gassner@mailbox.org>
_pkgname=youtube-dl
pkgname=$_pkgname-jxir
pkgver=2020.06.16.1.r6.ga115e0759
pkgrel=1
pkgdesc='A small command-line program to download videos from YouTube.com and a few more sites'
arch=('any')
url='https://github.com/rg3/youtube-dl'
license=('custom')
depends=('python')
makedepends=('git' 'python-setuptools' 'pandoc')
optdepends=('ffmpeg: for video post-processing'
'rtmpdump: for rtmp streams support'
'atomicparsley: for embedding thumbnails into m4a files'
'phantomjs: for openload support')
provides=("$_pkgname")
conflicts=("$_pkgname")
source=('git+https://github.com/rg3/youtube-dl.git')
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/$_pkgname"
git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "$srcdir/$_pkgname"
sed -i 's|etc/bash_completion.d|share/bash-completion/completions|' setup.py
sed -i 's|etc/fish/completions|share/fish/vendor_completions.d|' setup.py
}
build() {
cd "$srcdir/$_pkgname"
make pypi-files
}
package() {
cd "$srcdir/$_pkgname"
python setup.py install --root="$pkgdir/" --optimize=1
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|
