Add dmenu

1 files changed, 39 insertions, 0 deletions

diff --git a/dmenu/PKGBUILD b/dmenu/PKGBUILD
new file mode 100644
index 0000000..7d8852c
--- /dev/null
+++ b/dmenu/PKGBUILD
@@ -0,0 +1,39 @@
+# Maintainer: Justin Gassner <justin.gassner@web.de>
+
+_pkgname=dmenu
+pkgname=$_pkgname-jxir
+pkgver=4.7.4.gf0a5b75
+pkgrel=1
+pkgdesc='Generic menu for X'
+arch=('x86_64')
+url="https://tools.suckless.org/$_pkgname"
+license=('MIT')
+depends=('freetype2' 'libxft' 'libxinerama' 'sh')
+makedepends=('git')
+provides=("$_pkgname")
+conflicts=("$_pkgname")
+source=("git+https://git.jxir.de/$_pkgname")
+sha256sums=('SKIP')
+
+pkgver(){
+  cd "$_pkgname"
+  git describe --tags | sed 's/-/./g'
+}
+
+prepare() {
+  cd "$_pkgname"
+  mv config.def.h config.h
+}
+
+build() {
+  cd "$_pkgname"
+  make X11INC=/usr/include/X11 X11LIB=/usr/lib/X11
+  make X11INC=/usr/include/X11 X11LIB=/usr/lib/X11 FREETYPEINC=/usr/include/freetype2
+}
+
+package() {
+  cd "$_pkgname"
+  make PREFIX=/usr DESTDIR="$pkgdir" install
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$_pkgname/LICENSE"
+  install -Dm644 README "$pkgdir/usr/share/doc/$_pkgname/README"
+}